﻿// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Custom/Unlit/DetectionProximite"
{
	Properties
	{
		_MainTex ("Texture", 2D) = "white" {}
		_UserPosition("User position",Vector) = (200.0,0.0,0.0,0.0)
		_ManettePosition("Manette position",Vector) = (200.0,0.0,0.0,0.0)
		_DistanceMin("Distance min",Float) = 0.2 //meters
		_DistanceOpaque("Distance opaque",Float) = 0.1 //meters
	}
	SubShader
	{
		Tags { "Queue" = "Transparent" "RenderType"="Transparent" }
		LOD 100

		ZWrite Off
		Blend SrcAlpha OneMinusSrcAlpha

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			
			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f
			{
				float2 uv : TEXCOORD0;
				UNITY_FOG_COORDS(1)
				float4 vertex : SV_POSITION;
				float3 worldPos : TEXCOORD1;
			};

			sampler2D _MainTex;
			float4 _MainTex_ST;

			UNITY_INSTANCING_BUFFER_START(Props)
				float4 _UserPosition;
				float4 _ManettePosition;
				float _DistanceMin;
				float _DistanceOpaque;
			UNITY_INSTANCING_BUFFER_END(Props)

			v2f vert (appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = TRANSFORM_TEX(v.uv, _MainTex);
				o.worldPos = mul(unity_ObjectToWorld,v.vertex);
				UNITY_TRANSFER_FOG(o,o.vertex);
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				float d1 = distance(i.worldPos, _UserPosition);
				float d2 = distance(i.worldPos, _ManettePosition);
				clip(_DistanceMin - min(d1,d2));
				float alpha1 = 1.0 - (d1 - _DistanceOpaque) / (_DistanceMin - _DistanceOpaque);
				float alpha2 = 1.0 - (d2 - _DistanceOpaque) / (_DistanceMin - _DistanceOpaque);
				fixed4 col = tex2D(_MainTex, i.uv);
				col.a = col.a * max(alpha1, alpha2);
				return col;
			}
			ENDCG
		}
	}
}
